Bump to latest dev-python/service_identity release, required by net-im/matrix-python

dev-python/service_identity/service_identity-18.1.0.ebuild

@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Service identity verification for pyOpenSSL"
+HOMEPAGE="https://github.com/pyca/service_identity"
+SRC_URI="https://github.com/pyca/service_identity/archive/${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE=" MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+	dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	dev-python/attrs[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${PN/_/-}-${PV}"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -v -v -x || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}