dev-python/urllib3: add missing dependency to syncserver

dev-python/urllib3/Manifest

@@ -0,0 +1,2 @@
+DIST urllib3-1.25.3.tar.gz 262150 BLAKE2B a1d5de26a41e768bb8b36763a893fd2d3348502f561cf51f0b8354eaedda7bb1526695f7eff0807b466b541e957976ed9a84a755fea96b928cc2d12f2d7f280f SHA512 f75d83bd13db17ededf511e189fac0f4873784db288eb008aee844e2b9bc6a058ac2843398253014ea0e101494ecc61970c0afb0338f25be24acd7382ac7440f
+EBUILD urllib3-1.25.3.ebuild 1808 BLAKE2B 290d6051a180dc5905aeec8da4d7d1f17580d5f7967e8e150c169ce1ffbfcad4b49487479eb1c403d22312ad145bffca58fea43cd365ac158f7ec9c39c808161 SHA512 692efd8d71ad4e1a847ad1f595793fb6de00b74a7678ae1617fcc515e608f5489830683acf1b89cf226304d4e858238b43ef07f1f5f502b19da19b1e1cfcd2b3

dev-python/urllib3/urllib3-1.25.3.ebuild

@@ -0,0 +1,67 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} pypy{,3} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
+HOMEPAGE="https://github.com/shazow/urllib3"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+#RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/PySocks-1.5.6[${PYTHON_USEDEP}]
+	!~dev-python/PySocks-1.5.7[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2.0[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		>=www-servers/tornado-4.2.1[$(python_gen_usedep 'python*')]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+"
+
+# Testsuite written requiring mock to be installed under all Cpythons
+
+python_prepare_all() {
+	# skip appengine tests
+	rm -r test/appengine || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs SPHINXOPTS= html
+}
+
+python_test() {
+	# FIXME: get tornado ported
+	if [[ ${EPYTHON} == python* ]]; then
+		py.test -v || die "Tests fail with ${EPYTHON}"
+	fi
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}