dev-python/flake8: readd py2

dev-python/flake8/Manifest

@@ -0,0 +1,2 @@
+DIST flake8-3.7.9.tar.gz 150123 BLAKE2B fd46710c0dcce7d3dcb3d5fc8ff7a83a35315679fa838e68abafd5bdc342c13218706fec0dac3fc9a6d919971f1f846c855f00cbd60c925e979378e431dace0b SHA512 c3c753ad050d8a8f87f7c28c8a1c953ed9bd04f08b09512d9323152b4eebb57d67fbfb0f5317d629174fa12fa234e1a86d6a633dd951fff6a45330b1c4f62850
+EBUILD flake8-3.7.9.ebuild 1505 BLAKE2B b0a9015db2b1d7928404640ff59eb06599611334133ba3098e740d4b8edec9c622290818cbcc1fb11e6d67d2dc3b9ee1f4a5e292753479d69959128d9682ae34 SHA512 9a8d5f1939ec90b102b87c1d0799730e42cc4824b69914aa9255156b08b42683d37d8056a956788f3e0fa91b588dc31e16a6e42db839d9f22a17d96d88481cfe

dev-python/flake8/flake8-3.7.9.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="A wrapper around PyFlakes, pep8 & mccabe"
+HOMEPAGE="https://gitlab.com/pycqa/flake8 https://pypi.org/project/flake8/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 sparc x86"
+IUSE="test"
+
+# requires.txt inc. mccabe however that creates a circular dep
+RDEPEND="
+	>=dev-python/entrypoints-0.3[${PYTHON_USEDEP}]
+	<dev-python/entrypoints-0.4[${PYTHON_USEDEP}]
+	>=dev-python/pyflakes-2.1.0[${PYTHON_USEDEP}]
+	<dev-python/pyflakes-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pycodestyle-2.5.0[${PYTHON_USEDEP}]
+	<dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		dev-python/configparser[${PYTHON_USEDEP}]
+		dev-python/enum34[${PYTHON_USEDEP}]
+		dev-python/functools32[${PYTHON_USEDEP}]
+		dev-python/typing[${PYTHON_USEDEP}]
+	' -2)
+"
+PDEPEND="
+	>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
+	<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${PDEPEND}
+		>=dev-python/mock-2.0.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# don't treat warnings as errors when running tests
+	sed -r -i '/^[[:space:]]*error[[:space:]]*$/ d' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}