ACU/process/files/intradata_get/grades.pm

use v5.10.1;
use strict;
use warnings;
use Carp;

use ACU::Config;
use ACU::LDAP;
use ACU::Log;

# Function to generate student grades
sub grades_generate
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    if (! -e "$main::intradata/$year/$project_id/grades/") {
	mkdir "$main::intradata/$year/$project_id/grades/";
    }

    log DEBUG, "Generate list of students";

    # Create list of students to generate
    my @logins;
    if ($args->{unamed})
    {
	for (my $i = $args->{unamed}; $i > 0; $i--) {
	    push @logins, $args->{param}{$i};
	}
    }
    else
    {
	opendir(my $dh, "$main::intradata/$year/$project_id/traces/") or croak "can't opendir $main::intradata/$year/$project_id/traces/: $!";
	for my $dir (grep { ( ! /^\./ ) && -d "$main::intradata/$year/$project_id/traces/$_" } readdir($dh))
	{
	    opendir(my $dhm, "$main::intradata/$year/$project_id/traces/$dir") or croak "can't opendir $main::intradata/$year/$project_id/traces/$dir: $!";

	    for my $login (grep { ( ! /^\./ ) && -f "$main::intradata/$year/$project_id/traces/$dir/$_" } readdir($dhm))
	    {
		$login =~ s/\.xml$//;
		if (! grep { /^\Q$login\E$/ } @logins) {
		    push @logins, $login;
		}
	    }

	    closedir $dhm;
	}
	closedir $dh;
    }

    log TRACE, @logins;

    # Load grading file
    my $grading;
    if (exists $args->{files}{"grading.xml"}) {
	$grading = $args->{files}{"grading.xml"};
    }
    if (! $grading) {
	log ERROR, "Invalid grading.xml received!";
	return "Invalid grading.xml received!";
    }

    $grading = Grading->new($grading);

    opendir(my $dh, "$main::intradata/$year/$project_id/traces/") or croak "can't opendir $main::intradata/$year/$project_id/traces/: $!";
    my @trace_dirs = grep { ( ! /^\./ ) && -d "$main::intradata/$year/$project_id/traces/$_" } readdir($dh);
    closedir $dh;

    for my $login (@logins)
    {
	log DEBUG, "Generating grades for $login";
	for my $dir (@trace_dirs)
	{
	    log DEBUG, "Generating grades from $dir";
	    if (-f "$main::intradata/$year/$project_id/traces/$dir/$login.xml")
	    {
		open my $xmltrace, "<", "$main::intradata/$year/$project_id/traces/$dir/$login.xml" or croak "traces/$dir/$login.xml: $!";
		binmode $xmltrace;
		my $trace = Trace->new($xmltrace);
		close $xmltrace;

		log DEBUG, "Fill from file: traces/$dir/$login.xml";
		log TRACE, $trace->getIds;

		$grading->fill($trace->getIds);
	    }
	}

	log DEBUG, "Computed grades: ".$grading->compute($login);

	open my $xmlgrade, ">", "$main::intradata/$year/$project_id/grades/$login.xml" or croak "grades/$login.xml";
	binmode $xmlgrade;
	print $xmlgrade $grading->computeXML($login);
	close $xmlgrade;

	$grading->reset();
    }

    return "Ok";
}


sub grades_new_bonus
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $delete = $args->{param}{delete};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    if (! -e "$main::intradata/$year/$project_id/traces/") {
	mkdir "$main::intradata/$year/$project_id/traces/";
    }
    if (! -e "$main::intradata/$year/$project_id/traces/bonus/") {
	mkdir "$main::intradata/$year/$project_id/traces/bonus/";
    }

    for my $kfile (keys %{ $args->{files} })
    {
	log DEBUG, "Reading file $kfile";

	my $kbonus = $kfile;
	$kbonus =~ s/[^a-zA-Z0-9_-]/_/g;

	my @lines = split(/\n/, $args->{files}{$kfile});

	log TRACE, $args->{files}{$kfile};
	log TRACE, @lines;

	my $value;
	$value = 1 if (!$delete);

	# Looking for a global value 
	if ($lines[0] =~ /^(\d+)$/) {
	    $value = $1;
	    log INFO, "Setting global value to $value";
	    shift @lines;
	}

	for my $line (@lines)
	{
	    if ($line =~ /^([a-z0-9_-]+)(?:\s*:\s*([0-9.]+))?$/)
	    {
		my $login = $1;
		my $tvalue = $2 // $value;
		my $trace;

		if ($delete) {
		    log DEBUG, "Deleting bonus for $login";
		} else {
		    log DEBUG, "Applying bonus for $login:$tvalue";
		}

		if (-e "$main::intradata/$year/$project_id/traces/bonus/$login.xml") {
		    open my $xml, "<", "$main::intradata/$year/$project_id/traces/bonus/$login.xml" or croak $!;
		    binmode $xml;
		    $trace = Trace->new($xml);
		    close $xml;
		}
		elsif ($delete) {
		    next;
		}
		else {
		    $trace = Trace->new();
		}

		if ($delete) {
		    if ($tvalue && $tvalue == $trace->getIds($kbonus)) {
			$trace->delId($kbonus);
		    } else {
			$trace->delId($kbonus);
		    }
		} else {
		    $trace->addId($kbonus, $tvalue);
		}

		log DEBUG, "Updating $main::intradata/$year/$project_id/traces/bonus/$login.xml";

		open my $xml, ">", "$main::intradata/$year/$project_id/traces/bonus/$login.xml" or croak $!;
		print $xml $trace->toString();
		close $xml;
	    }
	    else {
		log WARN, "Invalid login $line, line skiped";
	    }
	}
    }

    return "Ok";
}

1;