project('evry-emoji', 'c',
  version: '0.1.0',
  default_options: ['c_std=gnu11', 'warning_level=2'],
)

cc = meson.get_compiler('c')

dep_e = dependency('enlightenment')
dep_evry = dependency('everything')

emoji_test_paths = [
  '/usr/share/unicode/emoji/emoji-test.txt',
  '/usr/share/unicode-data/emoji-test.txt',
]

emoji_test_file = ''
foreach p : emoji_test_paths
  if import('fs').exists(p)
    emoji_test_file = p
    break
  endif
endforeach

if emoji_test_file == ''
  error('Could not find emoji-test.txt. Searched: ' + ', '.join(emoji_test_paths))
endif

message('Found emoji data: ' + emoji_test_file)

module_arch = dep_e.get_variable(pkgconfig: 'module_arch')
module_dir = dep_e.get_variable(pkgconfig: 'modules')

install_dir = join_paths(module_dir, 'evry-emoji', module_arch)
data_dir = join_paths(module_dir, 'evry-emoji')

edje_cc = find_program('edje_cc')

edje_file = custom_target('e-module.edj',
  input: 'e-module.edc',
  output: 'e-module.edj',
  command: [edje_cc, '-v', '@INPUT@', '@OUTPUT@'],
  install: true,
  install_dir: data_dir,
)

shared_module('module',
  sources: ['src/e_mod_main.c'],
  dependencies: [dep_e, dep_evry],
  c_args: ['-DEMOJI_TEST_FILE="' + emoji_test_file + '"'],
  name_prefix: '',
  install: true,
  install_dir: install_dir,
)

install_data('module.desktop',
  install_dir: data_dir,
)