#! /usr/bin/env perl

use v5.10.1;
use strict;
use warnings;
use Carp;
use Pod::Usage;

use lib "../../";

use ACU::Log;
use ACU::LDAP;
use ACU::Grading;
use ACU::Process;
use ACU::Trace;

our $basedir = "/intradata";

my %actions = (
    "defense" => {
	"update" => \&update_defense,
    },
    "grades" => {
	"new_bonus" => \&grades_new_bonus,
	"generate" => \&grades_generate,
    },
    "project" => {
	"create" => \&update_project,
	"update" => \&update_project,
	"delete" => \&delete_project,
    }
);

sub create_tree($$)
{
    my $year = shift;
    my $project_id = shift;

    if (! -d "$basedir/$year/") {
	log ERROR, "No directory for year $year. Ask a root to create it.";
	return "No directory for year $year. Ask a root to create it.";
    }

    if (! -e "$basedir/$year/$project_id/") {
	mkdir "$basedir/$year/$project_id/";
    }

    return 0;
}


sub grades_generate
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    if (! -e "$basedir/$year/$project_id/grades/") {
	mkdir "$basedir/$year/$project_id/grades/";
    }

    log DEBUG, "Generate list of students";

    # Create list of students to generate
    my @logins;
    if ($args->{unamed})
    {
	for (my $i = $args->{unamed}; $i > 0; $i--) {
	    push @logins, $args->{param}{$i};
	}
    }
    else
    {
	opendir(my $dh, "$basedir/$year/$project_id/traces/") or croak "can't opendir $basedir/$year/$project_id/traces/: $!";
	for my $dir (grep { ( ! /^\./ ) && -d "$basedir/$year/$project_id/traces/$_" } readdir($dh))
	{
	    opendir(my $dhm, "$basedir/$year/$project_id/traces/$dir") or croak "can't opendir $basedir/$year/$project_id/traces/$dir: $!";

	    for my $login (grep { ( ! /^\./ ) && -f "$basedir/$year/$project_id/traces/$dir/$_" } readdir($dhm))
	    {
		$login =~ s/\.xml$//;
		if (! grep { /^\Q$login\E$/ } @logins) {
		    push @logins, $login;
		}
	    }

	    closedir $dhm;
	}
	closedir $dh;
    }

    log TRACE, @logins;

    # Load grading file
    my $grading;
    if (exists $args->{files}{"grading.xml"}) {
	$grading = $args->{files}{"grading.xml"};
    }
    if (! $grading) {
	log ERROR, "Invalid grading.xml received!";
	return "Invalid grading.xml received!";
    }

    $grading = Grading->new($grading);

    opendir(my $dh, "$basedir/$year/$project_id/traces/") or croak "can't opendir $basedir/$year/$project_id/traces/: $!";
    my @trace_dirs = grep { ( ! /^\./ ) && -d "$basedir/$year/$project_id/traces/$_" } readdir($dh);
    closedir $dh;

    for my $login (@logins)
    {
	log DEBUG, "Generating grades for $login";
	for my $dir (@trace_dirs)
	{
	    log DEBUG, "Generating grades from $dir";
	    if (-f "$basedir/$year/$project_id/traces/$dir/$login.xml")
	    {
		open my $xmltrace, "<", "$basedir/$year/$project_id/traces/$dir/$login.xml" or croak "traces/$dir/$login.xml: $!";
		binmode $xmltrace;
		my $trace = Trace->new($xmltrace);
		close $xmltrace;

		log DEBUG, "Fill from file: traces/$dir/$login.xml";
		log TRACE, $trace->getIds;

		$grading->fill($trace->getIds);
	    }
	}

	log DEBUG, "Computed grades: ".$grading->compute($login);

	open my $xmlgrade, ">", "$basedir/$year/$project_id/grades/$login.xml" or croak "grades/$login.xml";
	binmode $xmlgrade;
	print $xmlgrade $grading->computeXML($login);
	close $xmlgrade;

	$grading->reset();
    }

    return "Ok";
}

sub grades_new_bonus
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    if (! -e "$basedir/$year/$project_id/traces/") {
	mkdir "$basedir/$year/$project_id/traces/";
    }
    if (! -e "$basedir/$year/$project_id/traces/bonus/") {
	mkdir "$basedir/$year/$project_id/traces/bonus/";
    }

    for my $kfile (keys %{ $args->{files} })
    {
	log DEBUG, "Reading file $kfile";

	my $kbonus = $kfile;
	$kbonus =~ s/[^a-zA-Z0-9_-]/_/g;

	my @lines = split(/\n/, $args->{files}{$kfile});

	log TRACE, $args->{files}{$kfile};
	log TRACE, @lines;

	my $value = 1;
	# Looking for a global value 
	if ($lines[0] =~ /^(\d+)$/) {
	    $value = $1;
	    log INFO, "Setting global value to $value";
	    shift @lines;
	}

	for my $line (@lines)
	{
	    if ($line =~ /^([a-z0-9_-]+)(?:\s*:\s*([0-9.]+))?$/)
	    {
		my $login = $1;
		my $tvalue = $2 // $value;
		my $trace;

		log DEBUG, "Applying bonus for $login:$tvalue";

		if (-e "$basedir/$year/$project_id/traces/bonus/$login.xml") {
		    open my $xml, "<", "$basedir/$year/$project_id/traces/bonus/$login.xml" or croak $!;
		    binmode $xml;
		    $trace = Trace->new($xml);
		    close $xml;
		}
		else {
		    $trace = Trace->new();
		}

		$trace->addId($kbonus, $tvalue);

		log DEBUG, "Updating $basedir/$year/$project_id/traces/bonus/$login.xml";

		open my $xml, ">", "$basedir/$year/$project_id/traces/bonus/$login.xml" or croak $!;
		print $xml $trace->toString();
		close $xml
	    }
	    else {
		log WARN, "Invalid login $line, line skiped";
	    }
	}
    }

    return "Ok";
}

sub update_defense
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    my $defense_id = $args->{param}{defense_id};

    if (! $defense_id) {
	log ERROR, "No defense_id given.";
	return "No defense_id given";
    }

    my $defense;
    if (exists $args->{files}{"$defense_id.xml"}) {
	$defense = $args->{files}{"$defense_id.xml"};
    }
    if (! $defense) {
	log ERROR, "Invalid $defense_id.xml received!";
	return "Invalid $defense_id.xml received!";
    }

    log INFO, "Update $year/$project_id/defenses/$defense_id.xml";

    if (! -e "$basedir/$year/$project_id/defenses/") {
	mkdir "$basedir/$year/$project_id/defenses/";
    }
    if (! -e "$basedir/$year/$project_id/traces/") {
	mkdir "$basedir/$year/$project_id/traces/";
    }
    if (! -e "$basedir/$year/$project_id/traces/defense_$defense_id/") {
	mkdir "$basedir/$year/$project_id/traces/defense_$defense_id/";
	my ($login, $pass, $uid, $gid) = getpwnam("www-data");
	chown $uid, $gid, "$basedir/$year/$project_id/traces/defense_$defense_id/";
	chmod 0775, "$basedir/$year/$project_id/traces/defense_$defense_id/";
    }

    open my $out, ">", "$basedir/$year/$project_id/defenses/$defense_id.xml";
    print $out $defense;
    close $out;

    return "Ok";
}

sub update_project
{
    my $args = shift;

    my $project_id = $args->{param}{id};
    my $year = $args->{param}{year} // LDAP::get_year;

    if (! $project_id) {
	log ERROR, "No project_id given.";
	return "No project_id given";
    }

    my $butler;
    if (exists $args->{files}{"butler.xml"}) {
	$butler = $args->{files}{"butler.xml"};
    }
    if (! $butler) {
	log ERROR, "Invalid butler.xml received!";
	return "Invalid butler.xml received!";
    }

    log INFO, "Update $year/$project_id/butler.xml";

    return $_ if (create_tree($year, $project_id));

    open my $out, ">", "$basedir/$year/$project_id/butler.xml";
    print $out $butler;
    close $out;

    return "Ok";
}

sub delete_project
{
    log WARN, "delete_project: not implemented."
}


sub process_get
{
    my ($given_args, $args) = @_;

    my $type = $args->{param}{type};
    my $action = $args->{param}{action} // "update";

    if (! exists $actions{$type}{$action}) {
	log WARN, "Unknown action '$action' for $type.";
	return "Unknown action '$action' for $type.";
    }

    return $actions{$type}{$action}($args);
}

Process::register("intradata_get", \&process_get);